Transition Dynamics in Equilibrium Search: Technical Appendix

S. Nuray Akin and Brennan C. Platt

We provide this technical appendix to elucidate the intermediate steps of algebra.  The original file is written in Mathematica, and is downloadable in that format at MouseOver.  It is readable using Wolfram’s CDF reader (MouseOver).

Steady State Solutions

Steady state solutions are found by requiring the derivatives to be zero in each of the equilibrium differential equations (Eqs. 1 – 8).

Relaxed Steady State

Relaxed population (Eq. 8):

Solve[0==η-hr λ ,hr]

Desperate population (Eq. 7):

Solve[δ==λ hd,hd]

Fraction desperate (Eq. 1):

FullSimplify[ϕ->(hd/(hr+hd))/.%/.%%]

Relaxed price (Eqs. 5 and 6):

FullSimplify[Solve[ρ pr==x+λ (1-μ)(pr-pr)/.μ->0,pr]]

Desperate price (Eqs. 3 and 4):

FullSimplify[Solve[ρ pd==x-c+λ(1-μ) (pr-pd) /.%/.μ->0,pd]]

Strictly targeting the relaxed sellers is optimal (from Eq. 2) if:

FullSimplify[ϕ(y-ρ pd)≤y- ρ pr/.%/.%%/.%%%]

Verify that this is equivalent to the expression in Table 1 after substituting for β:

FullSimplify[β δ≤η/.β-> ((ρ c)/((λ+ρ)(y-x)))]

c δ ρ+η(x-y) (λ+ρ)≤0

((c δ ρ+(x-y) η (λ+ρ))/((δ+η) (λ+ρ)))≤0

Similarly, we can substitute for β in the desperate price equation:

FullSimplify[pd->(x/ρ)-((β(y-x))/ρ)/.β-> ((ρ c)/((λ+ρ)(y-x)))]

Dispersed Steady State

Relaxed population (Eq. 8):

Solve[0==η-hr λ (1-μ),hr]

Desperate population (Eq. 7):

Solve[δ==λ hd,hd]

Fraction desperate (Eq. 1):

FullSimplify[ϕ->(hd/(hr+hd))/.%/.%%]

Relaxed price (Eqs. 5 and 6):

FullSimplify[Solve[ρ pr==x+λ (1-μ)(pr-pr),pr]]

Equal profits (from Eq. 2):

FullSimplify[Solve[ϕ(y-ρ pd)==y- ρ pr,pd]/.%/.%%]

Using Eqs. 3 and 4, we can solve for μ:

FullSimplify[Solve[ρ pd==x-c+λ(1-μ) (pr-pd) /.pd->((y η-x (δ+η)+x δ μ)/(δ (-1+μ) ρ))/.pr->(x/ρ),μ]]

The final solution is then:

FullSimplify[{hd->(δ/λ),hr->-(η/(λ (-1+μ))),pd->((y η-x (δ+η)+x δ μ)/(δ (-1+μ) ρ)),pr->(x/ρ),ϕ->((δ-δ μ)/(δ+η-δ μ))}/.μ->((c δ ρ+(x-y) η (λ+ρ))/((x-y) η λ+c δ ρ))]

Verify that this is equivalent to the expression in Table 1 after substituting β:

FullSimplify[((c δ ρ+(x-y) η (λ+ρ))/((x-y) η λ+c δ ρ))==1-((ρ η)/((ρ+λ)(β δ-η)+ρ η))/.β-> ((ρ c)/((λ+ρ)(y-x)))]

Targeting both prices is optimal if μ < 1:

FullSimplify[1-((ρ η)/((ρ+λ)(β δ-η)+ρ η))<1]

η λ<β δ (λ+ρ)

and μ > 0:

FullSimplify[1-((ρ η)/((ρ+λ)(β δ-η)+ρ η))>0]

β δ (λ+ρ)>η (λ+ρ)

β δ >η

Both are true if β δ >η.

The desperate price, the relaxed population, and the fraction of desperate can be more succinctly expressed:

FullSimplify[{((-x η λ+y η λ-c δ ρ+x δ ρ)/(δ (ρ^2)))==((x-c)/ρ)+((η λ(y-x))/(δ (ρ^2))),-((c δ)/(x λ-y λ))-(η/ρ)==((β δ (λ+ρ))/(λ ρ))-(η/ρ),(((x-y) δ ρ)/((-x+y) η λ-(c-x+y) δ ρ))==((δ ρ)/(δ ρ(β+1)+(β δ-η) λ))}/.β-> ((ρ c)/((λ+ρ)(y-x)))]

Lemma 1

Relaxed Price Transition

The relaxed price (using Eqs. 5 and 6) has a unique solution, up to a constant:

FullSimplify[DSolve[{ρ pr[t]==x+pr'[t]},pr[t],t]]

However, if that constant is anything besides 0, the solution will diverge to +∞ or -∞.  Thus, the unique solution is:

pr[t]->(x/ρ)

Desperate Population Transition

The desperate population differential equation (Eq. 7) has a unique solution:

FullSimplify[DSolve[{hd'[t]==δ-λ hd[t],hd[0]==(δ/λ)+qd},hd[t],t]]

Relaxed Population Transition

The relaxed population differential equation (Eq. 8) depends on the phase due to μ.

Desperate Phase

In a desperate phase, μ = 1:

FullSimplify[DSolve[{hr'[t]==η-λ (1-μ[t])hr[t],hr[0]==(η/λ)+ qr}/.μ[t]->1,hr[t],t]]

Relaxed Phase

In a relaxed phase, μ = 0:

FullSimplify[DSolve[{hr'[t]==η-λ (1-μ[t])hr[t],hr[0]==(η/λ)+ qr}/.μ[t]->0,hr[t],t]]

Dispersed Phase

For a dispersed phase, offering pr or pd must be equally profitable (Π=0 in Eq. 2):

FullSimplify[Solve[ϕ[t](y-ρ pd[t])==y- ρ pr[t],pd[t]]/.pr[t]->(x/ρ)]

which means the derivative will also hold:

FullSimplify[D[pd[t]->((x-y+y ϕ[t])/(ρ ϕ[t])),t]]

From the relaxed population equation (Eq. 8), we find μ[t]:

Solve[hr'[t]==η-λ (1-μ[t])hr[t],μ[t]]

and substitute these into the desperate Bellman equation (Eq. 3 and 4):

FullSimplify[c+ρ pd[t]==x+λ (pd[t]-pr[t]) (-1+μ[t])+pd'[t]/.pr[t]-> (x/ρ)/.%/.%%/.%%%]

We then eliminate ϕ:

FullSimplify[%/.ϕ[t]->((hd[t])/(hr[t]+hd[t]))/.D[ϕ[t]->((hd[t])/(hr[t]+hd[t])),t]]

Assuming that the dispersed phase starts at time T with hd[T] = (δ/λ)+qd, then substitute for hd and its derivative:

FullSimplify[%/.hd[t]->(E^((-t+T) λ)) qd+(δ/λ)/.D[hd[t]->(E^((-t+T) λ)) qd+(δ/λ),t]]

We can then solve the differential equation of hr[t]:

Simplify[Assuming[λ>0&&ρ>0,FullSimplify[DSolve[((c (((δ+(E^((-t+T) λ)) qd λ))^2) ρ)/(λ^2))-(E^((-t+T) λ)) qd (x-y) λ hr[t]+(((x-y) (δ+(E^((-t+T) λ)) qd λ) (η+ρ hr[t]-2 hr'[t]))/λ)==0,hr[t],t]]]/.qd->(hd-(δ/λ))(E^((t-T) λ))]

The constant C[1] must be zero; otherwise this solution will eventually diverge.

hr->-((hd (c δ (ρ^2)+λ (c δ ρ+(x-y) η (λ+ρ)) Hypergeometric2F1[1,((λ+ρ)/(2 λ)),1+(ρ/(2 λ)),1-((hd λ)/δ)]))/((x-y) δ ρ (λ+ρ)))

We then use the following identity to have a simpler parameterization of the Hypergeometric function, using :

Hypergeometric2F1[a,c-b,c,(z/(z-1))]==(((1-z))^a)Hypergeometric2F1[a,b,c,z]

FullSimplify[{Hypergeometric2F1[a,c-b,c,z/(z-1)](1-z)^-a, Hypergeometric2F1[a,b,c,z]}/.a->1/.b->((λ+ρ)/(2 λ))/.c->1+(ρ/(2 λ))/.z->1-((hd λ)/δ) ]

FullSimplify[hr->-((hd (c δ (ρ^2)+λ (c δ ρ+(x-y) η (λ+ρ))((δ Hypergeometric2F1[(1/2),1,1+(ρ/(2 λ)),1-(δ/(hd λ))])/(hd λ))))/((x-y) δ ρ (λ+ρ)))]

The Hypergeometric function under these parameters can be equivalently expressed in terms of integrals.

FullSimplify[Hypergeometric2F1[a,b,c,z]==(Gamma[c]/(Gamma[b] Gamma[c-b])) Integrate[(t^(b-1) (1-t)^(c-b-1))/(1-t z)^a,{t,0,1}]]

FullSimplify[{(Gamma[c]/(Gamma[b] Gamma[c-b])),(t^(b-1) (1-t)^(c-b-1))/(1-t z)^a}/.a->(1/2)/.b->1/.c->1+(ρ/(2 λ))/.z->1-(δ/(hd λ))]

This is equivalent to Eq. 11 in the paper.

FullSimplify[-((hd (c δ (ρ^2)+((δ (c δ ρ+(x-y) η (λ+ρ)) Hypergeometric2F1[(1/2),1,1+(ρ/(2 λ)),1-(δ/(hd λ))])/hd)))/((x-y) δ ρ (λ+ρ)))==β hd+((β δ-η)/(2λ))(∫_0^1)((((1-s))^(-1+(ρ/(2 λ))))/(((1+s (-1+(δ/(hd λ)))))^(1/2)))\[DifferentialD]s/.β-> ((ρ c)/((λ+ρ)(y-x)))]

Desperate Price Transition

The desperate price differential equation (from Eqs. 3 and 4) also depends on the phase due to μ.

Desperate Phase

FullSimplify[DSolve[c+ρ pd[t]==x+λ (pd[t]-pr[t]) (-1+μ[t])+pd'[t]/.pr[t]-> (x/ρ)/.μ[t]->1,pd[t],t]]

Relaxed Phase

FullSimplify[DSolve[c+ρ pd[t]==x+λ (pd[t]-pr[t]) (-1+μ[t])+pd'[t]/.pr[t]-> (x/ρ)/.μ[t]->0,pd[t],t]]

Dispersed Phase

FullSimplify[pd[t]->((x-y+y ϕ[t])/(ρ ϕ[t]))/.ϕ[t]->((hd[t])/(hd[t]+hr[t]))]

Proposition 1

Profit in Relaxed Phase

To be in a relaxed equilibrium, buyers must weakly prefer offering the relaxed price.

FullSimplify[ϕ[t](y-ρ pd[t])≤y- ρ pr[t]/.ϕ[t]->((hd[t])/(hr[t]+hd[t]))/.pr[t]->(x/ρ)/.pd[t]->(x/ρ)-(c/(λ+ρ))+(E^(t (λ+ρ))) C[1]/.C[1]->0]

This is equivalent to:

c ρ hd[t]+(x-y) (λ+ρ) hr[t]≤0

((c ρ)/((y-x) (λ+ρ))) hd[t]≤ hr[t]

β hd[t]≤hr[t]

where β=((c ρ)/((y-x) (λ+ρ))).

Profit in the Desperate Phase

To be in a desperate equilibrium, buyers must weakly prefer offering the desperate price.

(x/ρ)-pd[t]-(((y- x)/ρ))((hr[t])/(hd[t]))≥0

Taking the derivative, we find:

FullSimplify[D[(x/ρ)-pd[t]-(((y- x)/ρ))((hr[t])/(hd[t])),t]]

The remaining calculations appear in the paper appendix.

Lemma 2

Derivative of Δ[hd]

The following is an equivalent expression of the 2F1 hypergeometric function.

FullSimplify[Hypergeometric2F1[1,b,d,z]==(d-1) z^(1-d) (1-z)^(d-b-1) Beta[z,d-1,b-d+1]]

Therefore, the dispersed path Δ[hd]==-((hd (c δ (ρ^2)+λ (c δ ρ+(x-y) η (λ+ρ)) Hypergeometric2F1[1,((λ+ρ)/(2 λ)),1+(ρ/(2 λ)),1-((hd λ)/δ)]))/((x-y) δ ρ (λ+ρ))) can be written:

Simplify[Δ[hd]->-((hd (c δ (ρ^2)+λ (c δ ρ+(x-y) η (λ+ρ)) ((d-1) z^(1-d) (1-z)^(d-b-1) Beta[z,d-1,b-d+1])))/((x-y) δ ρ (λ+ρ)))/.b->((λ+ρ)/(2 λ))/.d->1+(ρ/(2 λ))/.z->1-((hd λ)/δ)]

The derivative of Δ[hd] is then:

Simplify[D[Δ[hd]->-((hd (2 c δ ρ+(((((1-((hd λ)/δ)))^(-(ρ/(2 λ)))) (c δ ρ+x η (λ+ρ)-y η (λ+ρ)) Beta[1-((hd λ)/δ),(ρ/(2 λ)),(1/2)])/(Sqrt[((hd λ)/δ)]))))/(2 (x-y) δ (λ+ρ))),hd]]

To eliminate the Beta function from this derivative, we rearrange the equation for Δ[hd]:

(((Sqrt[((hd λ)/δ)])(((2 (y-x) δ (λ+ρ)Δ[hd])/hd)-2 c δ ρ))/((((1-((hd λ)/δ)))^(-(ρ/(2 λ)))) (c δ ρ+x η (λ+ρ)-y η (λ+ρ))))==Beta[1-((hd λ)/δ),(ρ/(2 λ)),(1/2)]

and then substitute for the Beta function in the derivative:

FullSimplify[Δ'[hd]->-((2 (c (δ-2 hd λ) ρ-x η (λ+ρ)+y η (λ+ρ))+(((((1-((hd λ)/δ)))^(-(ρ/(2 λ)))) (δ+hd (-λ+ρ)) (c δ ρ+x η (λ+ρ)-y η (λ+ρ))(((Sqrt[((hd λ)/δ)])(((2 (y-x) δ (λ+ρ)Δ[hd])/hd)-2 c δ ρ))/((((1-((hd λ)/δ)))^(-(ρ/(2 λ)))) (c δ ρ+x η (λ+ρ)-y η (λ+ρ)))))/(δ (Sqrt[((hd λ)/δ)]))))/(4 (x-y) (δ-hd λ) (λ+ρ)))]

This can be rearranged to match what is reported in Eq. 28 of the paper.

FullSimplify[Δ'[hd]->-((hd (x η-y η+c hd ρ)+(x-y) (δ+hd (-λ+ρ)) Δ[hd])/(2 hd (x-y) (-δ+hd λ)))/.c->β(ρ+λ)(y-x)/ρ]

Derivative of the desperate path when it approaches the dispersed path

Suppose that a desperate path intersects the desperate path at hd = (Subscript[(OverHat[h]), d]) and time T:

FullSimplify[DSolve[{hd'[t]==δ-λ  hd[t],hd[T]==(Subscript[(OverHat[h]), d])},hd[t],t]]

Consider its slope at time T:

FullSimplify[D[%,t]/.t->T]

The slope of the relaxed is always simply η, so the slope of the path is:

FullSimplify[η/(δ- (Subscript[(OverHat[h]), d]) λ)]

Intersection of the two derivatives (H)

So where does the dispersed and desperate paths intersect and equate?

FullSimplify[Solve[((hd (-η+hd β (λ+ρ))-(δ+hd (-λ+ρ)) Δ[hd])/(2 hd (-δ+hd λ)))==(η/(δ-λ hd)), Δ[hd]]/.β->((c ρ)/((y-x)(ρ + λ) ))]

So we define Q[hd]==-((hd (-x η+y η+c hd ρ))/((x-y) (δ+hd (-λ+ρ)))), so the intersection occurs at the hd where Δ[hd] == Q[hd]

Intersection properties

Δ is zero at hd = 0:

Assuming[δ>0&&λ hd>0,Δ[0]-> Limit[-((hd (c δ (ρ^2)+λ (c δ ρ+(x-y) η (λ+ρ)) Hypergeometric2F1[1,((λ+ρ)/(2 λ)),1+(ρ/(2 λ)),1-((hd λ)/δ)]))/((x-y) δ ρ (λ+ρ))),hd->0]]

Q is zero at hd = 0:

FullSimplify[Q[hd]->-((hd (-x η+y η+c hd ρ))/((x-y) (δ+hd (-λ+ρ))))/.hd->0]

The slope of Δ is infinite at 0:

Assuming[y>x>0&&ρ>0&&λ>0&&δ>0&&β δ>η,FullSimplify[Δ'[0]->Limit[((hd (-η+hd β (λ+ρ))-(δ+hd (-λ+ρ)) (-((hd (c δ (ρ^2)+λ (c δ ρ+(x-y) η (λ+ρ)) Hypergeometric2F1[1,((λ+ρ)/(2 λ)),1+(ρ/(2 λ)),1-((hd λ)/δ)]))/((x-y) δ ρ (λ+ρ)))))/(2 hd (-δ+hd λ))) /.c->β(ρ+λ)(y-x)/ρ,hd->0]]]

But the slope of Q is finite at 0:

FullSimplify[D[Q[hd]->-((hd (-x η+y η+c hd ρ))/((x-y) (δ+hd (-λ+ρ)))),hd]/.hd->0]

The second derivatives reveal that Q’ is increasing:

FullSimplify[D[D[Q[hd]->-((hd (-x η+y η+c hd ρ))/((x-y) (δ+hd (-λ+ρ)))),hd],hd]]

Q''[hd]->((2 δ ((y-x) η (λ-ρ)+c δ ρ))/((y-x) (((δ+hd (-λ+ρ)))^3)))>0

Meanwhile, Δ' is decreasing:

Δ[hd]->β hd+((β δ-η)/(2λ))(∫_0^1)((((1-s))^(-1+(ρ/(2 λ))))/(((1+s (-1+(δ/(hd λ)))))^(1/2)))\[DifferentialD]s

Take the first and second derivative of the integrand:

FullSimplify[D[((((1-s))^(-1+(ρ/(2 λ))))/(((1+s (-1+(δ/(hd λ)))))^(1/2))),hd]]

FullSimplify[D[%,hd]]

So the second derivative of Δ is:

Δ''[hd]->-((β δ-η)/(2λ))(∫_0^1)(((((1-s))^(-1+(ρ/(2 λ)))) s δ (s δ+4 hd λ (1-s)))/(4 (hd^4) (((1-s +s(δ/(hd λ))))^(5/2))))\[DifferentialD]s

The integrand is always positive because s < 1.

μ < 0 is also assured:

FullSimplify[0<1-((η-((-Δ[hd] (δ+hd (-λ+ρ))+hd (-η+hd β (λ+ρ)))/(2 hd (-δ+hd λ)))(δ-λ hd))/(λ Δ[hd]))]

Establish that  H<(δ/λ)-((η(y-x))/(λ c))

We verify that

Δ[(δ/λ)-((η(y-x))/(λ c))]<Q[(δ/λ)-((η(y-x))/(λ c))]

Using F to represent the integral:

FullSimplify[-((hd (-x η+y η+c hd ρ))/((x-y) (δ+hd (-λ+ρ))))>β hd+(((β δ-η))/(2 λ))F/.hd->(δ/λ)-((η(y-x))/(λ c))/.β->((c ρ)/((y-x)(ρ+λ) ))]

This rearranges to:

(2 λ-F ρ)( c δ-(y-x) η)+λ η(y-x) F >0

Note that the integrand is smaller than (((1-s))^((ρ-2λ)/(2λ))):

FullSimplify[((((1-s))^(-1+(ρ/(2 λ))))/(((1+s (-1+(δ/(hd λ)))))^(1/2)))<(((1-s))^((ρ-2λ)/(2λ)))]

So the integral must be smaller than ((2λ)/ρ):

Assuming[ρ>0&&λ>0,(∫_0^1)(((1-s))^((ρ-2λ)/(2λ)))\[DifferentialD]s]

Lemma 3

Show c H - (x-y) Δ(H) > 0

Since Δ(H) = Q(H) by definition, we can substitute for Δ(h) to get a simple answer.

FullSimplify[c hd>(y-x)(-((hd (-x η+y η+c hd ρ))/((x-y) (δ+hd (-λ+ρ)))))/.hd->H]

The last term is always positive because H< (δ/λ), while the first is positive because (δ/λ)-(((y-x) η)/(λ c))>H.

Show c- (x-y) Δ’(H) > 0

Use the derivative of the desperate path since these are equal at H:

FullSimplify[c-(y-x)(η/(δ-λ hd))>0]

FullSimplify[c(δ-λ hd)-(y-x)η>0]

Establish that c hd* - (x-y) Δ(hd*) > 0 and c- (x-y) Δ’(hd*) > 0

FullSimplify[c hd-(y-x)( β hd+(((β δ-η)Hypergeometric2F1[(1/2),1,1+(ρ/(2 λ)),1-(δ/(λ hd))])/ρ))/.hd->(( δ)/λ)/.β-> ((c ρ)/((y-x)(λ+ ρ) ))]

FullSimplify[D[c hd-(y-x)( β hd+(((β δ-η)Hypergeometric2F1[(1/2),1,1+(ρ/(2 λ)),1-(δ/(λ hd))])/ρ)),hd]/.hd->(( δ)/λ)/.β-> ((c ρ)/((y-x)(λ+ ρ) ))]

Establish that c - (y-x) Δ’ > 0 when hd < hd*

Substitute Δ’ with the previously found simplification of the derivative:

FullSimplify[c-(y-x)((-Δ[hd] (δ+hd (-λ+ρ))+hd (-η+hd β (λ+ρ)))/(2 hd (-δ+hd λ)))>0/.β-> ((c ρ)/((y-x)(λ+ ρ) ))]

Collect[ c-((hd (x η-y η+c hd ρ)+(x-y) (δ+hd (-λ+ρ)) Δ[hd])/(2 hd (-δ+hd λ))),Δ[hd]]>0

FullSimplify[(c-((x η-y η+c hd ρ)/(2 (-δ+hd λ))))/((((x-y) (δ+hd (-λ+ρ)) )/(2 hd (-δ+hd λ))))]>Δ[hd]

((hd (x-y) η+c hd (2 δ+hd (-2 λ+ρ)))/((y-x) (δ+hd (-λ+ρ))))>hr

We know that hr has to be less than its steady state value, which holds true for all hd greater than:

Solve[((hd (x-y) η+c hd (2 δ+hd (-2 λ+ρ)))/((y-x) (δ+hd (-λ+ρ))))==-(η/ρ)+((c δ )/((y-x)λ)),hd]

hd>((c δ ρ-λ η(y-x))/(c (2 λ-ρ) ρ))

On the other hand, we can see that the derivative is positive whenever H < hd < (( c δ-(y-x) η ρ)/(λ c)):

the intersection of the derivatives happens at:

hr->-((hd (-x η+y η+c hd ρ))/((x-y) (δ+hd (-λ+ρ))))

We know from Lemma 2 that for hd > H, Q[hd] > Δ[hd].  So recalling the condition for c - (y-x) Δ’ > 0, which was:

((hd (x-y) η+c hd (2 δ+hd (-2 λ+ρ)))/((y-x) (δ+hd (-λ+ρ))))>Δ[hd]

we will check that when Q[hd] replaces Δ[hd], the tighter inequality holds:

FullSimplify[((hd (x-y) η+c hd (2 δ+hd (-2 λ+ρ)))/((y-x) (δ+hd (-λ+ρ))))>-((hd (-x η+y η+c hd ρ))/((x-y) (δ+hd (-λ+ρ))))]

(x-y) η+c (δ-hd λ)>0

(( c δ-(y-x) η ρ)/(λ c))> hd

So this ensures that c - (y-x) Δ’ > 0 so long as (( c δ-(y-x) η ρ)/(λ c))> hd.

Now we just verify that the interval (H,(( c δ-(y-x) η ρ)/(λ c))) and (((c δ ρ-λ η(y-x))/(c (2 λ-ρ) ρ)),(δ/λ)) overlap:

((c δ ρ-λ η(y-x))/(c (2 λ-ρ) ρ))<(( c δ-(y-x) η ρ)/(λ c))

This is equivalent to:

FullSimplify[c λ(c δ ρ-λ η(y-x))<(c (2 λ-ρ) ρ)(c δ-(y-x) η ρ)]

c (c δ ρ (λ-ρ)+(y-x) η (λ(λ-2(ρ^2))+(ρ^3)))>0

Establish that c - (y-x) Δ’ > 0 when (δ/(λ-ρ)) > hd > (δ/λ)

Substitution for Δ’ previously yielded this:

But now that -δ+hd λ>0 and δ+hd (-λ+ρ)<0, the inequality reverses when dividing:

FullSimplify[(c-((x η-y η+c hd ρ)/(2 (-δ+hd λ))))/((((x-y) (δ+hd (-λ+ρ)) )/(2 hd (-δ+hd λ))))]<Δ[hd]

The RHS is rising, while the LHS is falling.  To show the latter, take its derivative:

FullSimplify[D[((hd (x-y) η+c hd (2 δ+hd (-2 λ+ρ)))/((y-x) (δ+hd (-λ+ρ)))),hd]]

This derivative is strictly decreasing:

FullSimplify[D[(((-x+y) δ η+c (-2 (((δ-hd λ))^2)+hd (-2 δ+3 hd λ) ρ-(hd^2) (ρ^2)))/((x-y) (((δ+hd (-λ+ρ)))^2))),hd]]<0

The sign holds because λ > ρ, y > x, and hd<(δ/(λ-ρ)).

So (((-x+y) δ η+c (-2 (((δ-hd λ))^2)+hd (-2 δ+3 hd λ) ρ-(hd^2) (ρ^2)))/((x-y) (((δ+hd (-λ+ρ)))^2))) takes its largest value at the smallest value of its domain, hd =(δ/λ)

FullSimplify[((-(y-x) δ η+c (2 (((δ-hd λ))^2)+hd (2 δ-3 hd λ) ρ+(hd^2) (ρ^2)))/((y-x) (((δ+hd (-λ+ρ)))^2)))/.hd->(δ/λ)]<0

-(((y-x) η (λ^2)+c δ (λ-ρ) ρ)/((y-x) δ (ρ^2)))<0

So the derivative is negative at its highest value, and only becomes more negative as hd increases.

Establish that c - (y-x) Δ’ > 0 when (δ/(λ-ρ)) < hd

Substitution for Δ’ previously yielded this:

When -δ+hd λ>0 and δ+hd (-λ+ρ)>0, the inequality remains unchanged when dividing:

FullSimplify[(c-((x η-y η+c hd ρ)/(2 (-δ+hd λ))))/((((x-y) (δ+hd (-λ+ρ)) )/(2 hd (-δ+hd λ))))]>Δ[hd]

The LHS is bounded below by ((c (2 λ-ρ))/((y-x) (λ-ρ)))hd:

FullSimplify[((hd (x-y) η+c hd (2 δ+hd (-2 λ+ρ)))/((y-x) (δ+hd (-λ+ρ))))>((c (2 λ-ρ))/((y-x) (λ-ρ)))hd]

hd (y-x) (λ-ρ) ((y-x) η (λ-ρ)+c δ ρ) (hd (λ-ρ)-δ)>0

All parenthetical terms are positive.

The term ((c (2 λ-ρ))/((y-x) (λ-ρ))) is relevant because it is the slope in the limit:

Limit[D[((hd (x-y) η+c hd (2 δ+hd (-2 λ+ρ)))/((y-x) (δ+hd (-λ+ρ)))),hd],hd->∞]

Next, we can bound Δ(hd) above with ((c δ ρ (λ+ρ)-(y-x) η (λ^2))/((y-x) δ ρ (2 λ+ρ)))hd-(((y-x) η (λ+ρ)-c δ ρ)/((y-x) ρ (2 λ+ρ))).  The slope comes from the derivative at steady state:

FullSimplify[D[β hd+(((β δ-η)Hypergeometric2F1[(1/2),1,1+(ρ/(2 λ)),1-(δ/(λ hd))])/ρ),hd]/.hd->(δ/λ)/.β-> ((c ρ)/((y-x)(λ+ρ) ))]

((δ ρ (λ+ρ)c-η (y-x)(λ^2))/((y-x) δ ρ (2 λ+ρ)))

while the intercept ensures that ((c δ ρ (λ+ρ)-(y-x) η (λ^2))/((y-x) δ ρ (2 λ+ρ)))hd-(((y-x) η (λ+ρ)-c δ ρ)/((y-x) ρ (2 λ+ρ)))==Δ[hd] at steady state.

FullSimplify[((c δ ρ (λ+ρ)-(y-x) η (λ^2))/((y-x) δ ρ (2 λ+ρ)))hd-(((y-x) η (λ+ρ)-c δ ρ)/((y-x) ρ (2 λ+ρ)))==hr/.hd->(δ/λ)/.hr->-((c δ)/(x λ-y λ))-(η/ρ)]

Since Δ’’[hd]<0 as previously noted, this linear function will be greater than Δ[hd] for all hd > (δ/λ).

So then we simply compare the bounds:

FullSimplify[((c (2 λ-ρ))/((y-x) (λ-ρ)))hd>((-x η (λ^2)+y η (λ^2)-c δ ρ (λ+ρ))/((x-y) δ ρ (2 λ+ρ)))hd-((c δ ρ+(x-y) η (λ+ρ))/((x-y) ρ (2 λ+ρ)))]

With rearrangement, this becomes:

Collect[(x-y) η (λ^2) (δ+hd λ)+λ (hd (-x+y) η λ+c δ (δ-3 hd λ)) ρ-δ (c δ+(x-y) η) (ρ^2)<0,hd]

FullSimplify[(x-y) δ η (λ^2)+c (δ^2) λ ρ-δ (c δ+(x-y) η) (ρ^2)]<hd FullSimplify[(λ^2)((y-x) η (λ-ρ)+3c δ ρ)]

((δ (λ-ρ) (c δ ρ-(y-x) η (λ+ρ)))/((λ^2)((y-x) η (λ-ρ)+3c δ ρ)))<hd

Knowing that (δ/λ)<hd, we show that the l.h.s. is smaller than (δ/λ):

FullSimplify[((δ (λ-ρ) (c δ ρ-(y-x) η (λ+ρ)))/((λ^2)((y-x) η (λ-ρ)+3c δ ρ)))<(δ/λ)]

(y-x) η (λ-ρ)+3 c δ ρ>0

Proposition 2

Equations for R and S

For either degenerate phase, hd follows the same transition.  Let (OverHat[hd])=qd+(δ/λ).  Then

FullSimplify[Solve[hd==(E^(-t λ)) ((OverHat[hd])-(δ/λ))+(δ/λ),t]/.C[1]->0]

In a relaxed phase, this can be substituted into hr as follows:

FullSimplify[hr->(E^(-t λ)) (Δ[(OverHat[hd])]-(η/λ))+(η/λ)/.%]

In a desperate phase, the substitution becomes:

FullSimplify[hr->(Δ[(OverHat[hd])]-(η/λ))+η (t+(1/λ))/.%%]

Case 2: Profit in the relaxed region

The ratio of relaxed to desperate is always falling in the relaxed region:

FullSimplify[D[((hr[t])/(hd[t])),t]]

FullSimplify[%/.hr'[t]->η-λ hr[t]/.hd'[t]->δ-λ hd[t]]

This is negative because hr[t] > β hd[t], and β δ > η, so hr[t] > (η/δ) hd[t].

The relative profit function can be rewritten as follows with the same zeros and signs:

((hd[t])/(hd[t]+hr[t]))((y/ρ)-pd[t])-((y-x)/ρ)

(y/ρ)-pd[t]-((y-x)/ρ)(1+((hr[t])/(hd[t])))

(x/ρ)-pd[t]-((y-x)/ρ)((hr[t])/(hd[t]))

The derivative on profit is:

-pd'[t]-((y-x)/ρ)((((hr[t])/(hd[t]))))'

Since pd’[t] < 0 and ((((hr[t])/(hd[t]))))'<0, the derivative is always positive.  Since profit equals 0 at time Tr and is strictly increasing until then, the profit must be negative for all t < Tr.

Case 3: Profit in the desperate region

To verify that (OverHat[hd]) is unique, take the derivative of the S function:

FullSimplify[D[((η Log[((δ-λ (OverHat[hd]))/(δ-hd λ))])/λ)+Δ[(OverHat[hd])],(OverHat[hd])]]

Recall that these are equal at (OverHat[hd])=H.  Next take the second derivative:

FullSimplify[D[D[((η Log[((δ-λ (OverHat[hd]))/(δ-hd λ))])/λ)+Δ[(OverHat[hd])],(OverHat[hd])],(OverHat[hd])]]

This is always negative.

We next demonstrate that profit is always positive in this region.

First consider when hd[0]≥(δ/λ).  By multiplying by (hd+hr), we can express the profit as:

((x/ρ)-pd[t])hd[t]-((y-x)/ρ)hr[t]

So the derivative w.r.t. t is:

((x/ρ)-pd[t])hd'[t]-pd'[t]hd[t]-((y-x)/ρ)hr'[t]

It is always the case that (x/ρ)>pd[t] and hd[t]≥0.  In a desperate phase, we also have hr'[t]=η>0 and pd'[t]=ρ (Subscript[a, d])(e^(ρ t))>0.  Finally, if hd[t]≥(δ/λ), then hd'[t]≤0.  Thus, the derivative of profit is negative. At t = Td, profit is zero, so profit must be positive for t < Td.

Next, consider hd[0]<(δ/λ).

First, we derive the required constant (Subscript[a, d]).  At time Td, the definition for the desperate price must equate in both the dispersed and desperate phases since the Bellman equation is continuous.  The dispersed definition is:

FullSimplify[pd[t]->((x-y+y ϕ[t])/(ρ ϕ[t]))/. ϕ[t]->(zd/(Δ[zd]+zd))/.t->Td]

while the desperate definition is:

FullSimplify[Solve[((-c+x+(E^(t ρ)) ρ C[1])/ρ)==pd[Td]/.t->Td/.%,C[1]]]

We then substitute into the profit function, using hr = S(hd,zd):

FullSimplify[((x/ρ)-pd[t])hd-((y-x)/ρ)hr/.pd[t]->((-c+x+(E^(t ρ)) ρ  ad)/ρ)/.ad->(((E^(-Td ρ)) (c zd+(x-y) Δ[zd]))/(zd ρ))/.Td->((Log[((qd λ)/(-δ+zd λ))])/λ)/.t->((Log[((qd λ)/(-δ+hd λ))])/λ)/.hr->(Δ[zd]-(η/λ)Log[((-δ+hd λ)/(-δ+zd λ))])]

(((y-x) zd (η Log[((δ-hd λ)/(δ-zd λ))]-λ Δ[zd])+hd λ (c zd-(((((-δ+zd λ)/(-δ+hd λ))))^(ρ/λ))  (c zd+(x-y) Δ[zd])))/(zd λ ρ))

Notice that at hd = (δ/λ)-qd, positive profits rearrange to be the assumption for Case 3 of Proposition 2:

FullSimplify[((x/ρ)-pd[t])hd-((y-x)/ρ)hr>0/.pd[t]->((-c+x+(E^(t ρ)) ρ  ad)/ρ)/.t->0/.hr->hr[0]/.hd->hd[0]/.qd-> hd[0]-(δ/λ)]

((c-ρ ad)/(y-x)) hd[0]> hr[0]

And of course, profits must be zero as it reaches the dispersed path:

FullSimplify[((x/ρ)-pd[t])hd-((y-x)/ρ)hr==0/.pd[t]->((-c+x+(E^(t ρ)) ρ C[1])/ρ)/.C[1]->(((E^(-Td ρ)) (c zd+(x-y) Δ[zd]))/(zd ρ))/.t->Td/.hr->Δ[zd]/.hd->zd]

We next examine the second derivative of (OverHat[Π]) w.r.t. hd:

FullSimplify[D[(((y-x) zd (η Log[((δ-hd λ)/(δ-zd λ))]-λ Δ[zd])+hd λ (c zd-(((((-δ+zd λ)/(-δ+hd λ))))^(ρ/λ))  (c zd+(x-y) Δ[zd])))/(zd λ ρ)),hd]]

FullSimplify[D[((c δ+x η-y η-c hd λ-(((((((δ-zd λ)/(δ-hd λ))))^(ρ/λ)) (δ+hd (-λ+ρ)) (c zd+(x-y) Δ[zd]))/zd))/((δ-hd λ) ρ)),hd]]

-(((y-x) zd η λ+(((((δ-zd λ)/(δ-hd λ))))^(ρ/λ)) ρ (2 δ+hd (-λ+ρ)) (c zd+(x-y) Δ[zd]))/(zd (((δ-hd λ))^2) ρ))

Note that the denominator is positive.  So is c zd+(x-y) Δ[zd], per Lemma 3.  The term (((((δ-zd λ)/(δ-hd λ))))^(ρ/λ)) ρ (2 δ+hd (-λ+ρ))is positive if hd <((2δ )/λ).  Thus, when hd <((δ )/λ), the second derivative of profits is negative for all hd[0] < hd < zd.  Thus, profits must be positive for all hd[0] < hd < zd, since they must reach 0 at hd = zd, and cannot fall then rise again.

Case 4: Profit in the bifurcated region

The constants in the desperate price equations are determined as follows:

In the initial relaxed phase, it must follow:

pd[t]->(x/ρ)-(c/(λ+ρ))+(E^(t (λ+ρ))) C[2]

up until it meets up with price in the desperate phase at time Tr:

pd[t]->((-c+x+(E^(t ρ)) ρ C[1])/ρ)

which ultimately meets with the price in the dispersed phase at time Td:

FullSimplify[pd[t]->((x-y+y ϕ[t])/(ρ ϕ[t]))/. ϕ[t]->(zd/(Δ[zd]+zd))/.t->Td]

So the constants are:

FullSimplify[Solve[((-c+x+(E^(t ρ)) ρ C[1])/ρ)==((x zd+(x-y) Δ[zd])/(zd ρ))/.t->Td,C[1]]]

FullSimplify[Solve[(x/ρ)-(c/(λ+ρ))+(E^(t (λ+ρ))) C[2]==((-c+x+(E^(t ρ)) ρ C[1])/ρ)/.t->Tb,C[2]]]

To verify that the second constant is negative, we rearrange as follows (letting F represent the integral in Δ):

FullSimplify[(((E^(-Tb (λ+ρ))) (-c λ+(E^(Tb ρ)) ρ (λ+ρ) ad))/(ρ (λ+ρ)))/.ad->(((E^(-Td ρ)) (c zd+(x-y) Δ[zd]))/(zd ρ))]

-(((E^(-Tb (λ+ρ))) )/(ρ (λ+ρ)))(((c λ zd-(λ+ρ) (c zd-(y-x) Δ[zd])(E^((Tb-Td) ρ)))/zd))

-(((E^(-Tb (λ+ρ))) )/(ρ (λ+ρ)))(((c λ zd-(λ+ρ) (c zd-(y-x)(β zd+((β δ-η)/(2 λ))F))(E^((Tb-Td) ρ)))/zd))

-(((E^(-Tb (λ+ρ))) )/(ρ (λ+ρ)))(((FullSimplify[c λ zd-(λ+ρ) (c zd-(y-x)(((ρ c)/((ρ+λ)(y-x))) zd+((β δ-η)/(2 λ))F))(E^((Tb-Td) ρ))])/zd))

-(((E^(-Tb (λ+ρ))) (c zd λ(1-(E^((Tb-Td) ρ)))+(( F (y-x) (β δ-η) (λ+ρ))/(2 λ))(E^((Tb-Td) ρ))))/(zd ρ (λ+ρ)))

This is always negative.

The ratio of relaxed to desperate is also falling in the initial relaxed phase:

FullSimplify[D[((hr[t])/(hd[t]))/.hr[t]->(E^(-t λ)) qr+(η/λ)/.hd[t]->(E^(-t λ)) qd+(δ/λ),t]]

We need only to verify that qr δ > qd η, or equivalently, hr(0) δ > hd(0) η.  Suppose this were not the case.  Then hr(0) < hd(0) (η/δ) <hd(0)((c-ρ ad)/((y-x))), making Case 3 applicable rather than Case 4.  This is because:

(η/δ)<((c-(((E^(-Td ρ)) (c zd+(x-y) Δ[zd]))/(zd )))/((y-x)))

(η/δ)<((c-(((E^(-Td ρ)) (c zd+(x-y)(β zd+((β δ-η)/(2 λ))F)))/(zd )))/((y-x)))

FullSimplify[(η/δ)<((c-(((E^(-Td ρ)) (c zd+(x-y)(β zd+((β δ-η)/(2 λ))F)))/(zd )))/((y-x)))/.c->β (y-x)(λ+ρ)/ρ]

(E^(Td ρ)) zd δ λ ρ ((((F δ)/(2λ))+zd (E^(Td ρ))) (β δ-η) ρ+zd ((E^(Td ρ))-1)β δ λ)>0

This is always positive because β δ > η and (e^(Td ρ))>1.